Stop signal task

Introduction

In a stop-signal task, you are asked to respond quickly, except when a stop signal arrives.

Once you have initiated a movement, even when just "in the brain" as a plan, it is hard to stop.

Stop-signal tasks are a variation on go/no-go. Introduced by Lappin and Eriksen in 1966, and further developed by Gordon Logan and colleagues, the tasks measure how good a person is in withholding a response.

In "standard" go/no-go paradigms, there are stimuli you need to respond to, and there are stimuli that you should absolutely not respond to. That is, typically, not a very difficult task to do.

In contrast, the stop-signal task is a very difficult task. In this task, need to respond to stimuli, but on some trials, you will get a "stop" signal. Because the stop signal comes after the imperative stimulus, you will need to stop the response you might already have initiated. Response initiation is, of course, not just physical process, but also a mental process, and the stop-signal task shows that at some point, this can not be stopped anymore!

Gordon Logan is one of the leading researchers in this area. A recent article (2015) is listed below in the references.

About this implementation

In this example, a left or right pointing arrow is presented within a white circle. You need to respond to a left of right green pointing arrow with the following keys:

left pointing arrow: b key
right pointing arrow: n key

Now, that is simple! Although it is a simple task, you need to get used to responding quickly, though; you must respond within 500 ms (half a second). This is quite fast, but then, the task is very simple and most people can do this.

Early on you might make some mistakes, but you will get used to it after doing this for a while (initially, you will get some mistakes telling you that you should have pressed — you might have pressed, but you were just not fast enough).

The difficulty is that after a training phase, the white circle can become red after the arrow has been presented. The red circle is your stop signal, and you should NOT respond. As you will experience here for yourself, that is very difficult.

The timing in this implementation is set very tightly (the maximum response time in any trial is only 500 ms). If this is too hard, download the PsyToolkit script files and upload them in your own PsyToolkit account. You can set the parameters (replace 500 throught 2000).

The demo takes less than 5 minutes to complete.

Timing of trials

There are go and no-go trials.

In go trials, you need to press the button. The green arrow appears and there is no stop signal. The green arrow will be presented up to 500 ms. If you have not responded within that time, you get an error message.

In no-go trials, the white circle will turn red in the time between 100 ms and 450 ms following the onset of the stimulus. In other words, the stop signal (the white circle turning red) can be show earliers 100 ms after the onset of the green arrow and latest 450 ms after the green arrow.

In this demonstration there are two blocks. In the first block, all trials are go trials to get you used to the basic task. In the following block, there are 30 go trials and 10 nogo trials.

Run the demo

Click here to run a demo of the task

Data output file

In PsyToolkit, the data output file is simply a textfile. The save line of the PsyToolkit experiment script determines what is being saved in the data output file. Typically, for each experimental trial, you would have exactly one line in your text file, and each number/word on that line gives you the information you need for your data analysis, such as the condition, response speed, and whether an error was made.

Meaning of the columns in the output datafile. You need this information for your data analysis.

Colum	Meaning
1	trial type (go or nogo)
2	required response (left or right)
3	when the stop signal is shown (or 0 if not)
4	response time 1
5	status 1 (1=correct, 2=wrong, 3=timeout)
6	response time 2 (only in no go trials)
7	status 2 (only in no go trials; 1=correct, 2=wrong, 3=timeout)
8	1=trial is correct ; 0=trial is not correct

In go trials, there is simply a response time and status (columns 4 and 5). However, in no go trials, it is still possible people respond before the nogo signal (in that case response time 1 and 2 show this). If people get the no-go signal, a second response time and status are given in case people respond.

Analysis and data interpretation

The interesting part of the data is how many times people are unable to stop to respond on a no-go trial. In this paradigm, the no-go trials are when a stop signal was shown around the green arrow. You would expect that the better people attend, the better they are able to withhold their response.

For such an analysis, you would set the meaning of the columns in the data file as follows:

Dependent variable column: 4
Which column has status (correct=1)?: 5
Grouping variable: 3
Include only data lines starting with: nogo

For this, you are only interested in the PE (i.e., percentage of error data).

PsyToolkit code

Click to expand the PsyToolkit script code (part of zip file below)

# stop signal task

options
  bitmapdir stimuli    # the folder that contains the stimuli bitmaps
  set &d 0 # dummy variable
  set &iti 750  # inter trial interval (ITI)

bitmaps
  frame
  leftarrow
  rightarrow
  leftarrownogo
  rightarrownogo
  fixpoint1
  fixpoint2
  fixpoint3
  wrongkey
  shouldnothavepressed1
  shouldnothavepressed2
  shouldhavepressed1
  shouldhavepressed2
  instruction1
  instruction2

fonts
  arial 20

part nice_fixpoint
  show bitmap fixpoint1
  delay 75
  show bitmap fixpoint2
  delay 75
  show bitmap fixpoint3
  delay 75
  clear -1 -2 -3
  show bitmap fixpoint2
  delay 75
  clear -1
  show bitmap fixpoint1
  delay 200
  clear -1

table gotable
  "go   left"  leftarrow  1
  "go   right" rightarrow 2

table nogotable
  "nogo left"  leftarrow  1 leftarrownogo
  "nogo right" rightarrow 2 rightarrownogo

task go
  table gotable
  set $trialcorrect 1
  keys b n
  show bitmap frame #1
  delay 500
  part nice_fixpoint # show nice fixpoint
  show bitmap @2 # show the arrow (the go signal)
  readkey @3 500 # max response time 500 ms
  clear -1
  ### feedback
  if STATUS == TIMEOUT
    show bitmap shouldhavepressed1
    delay 250
    clear -1
    show bitmap shouldhavepressed2
    delay 250
    clear -1
    show bitmap shouldhavepressed1
    delay 250
    clear -1
    show bitmap shouldhavepressed2
    delay 250
    clear -1
    show bitmap shouldhavepressed1
    delay 250
    clear -1
    error
    set $trialcorrect 0
  fi
  if STATUS != TIMEOUT && STATUS != CORRECT
    show bitmap wrongkey
    delay 2000
    clear -1
    error
    set $trialcorrect 0    
  fi
  delay &iti
  save @1 &d RT STATUS &d &d $trialcorrect

task nogo
  table nogotable
  set $trialcorrect 1  
  keys b n
  show bitmap frame
  delay 500
  part nice_fixpoint
  set $nogodelay random 100 450 50
  set $resttime expression 500 - $nogodelay
  show bitmap @2 # the arrow
  readkey @3 $nogodelay # 'wait' until nogo delay is over
  set $rt1 RT
  set $status1 STATUS
  ## there are two possibilities:
  ## 1: Person has not yet responded
  ## 2: Person has responded, i.e., before stop signal, so that would be correct
  if $status1 == TIMEOUT ### only if button NOT pressed show NOGO stimulus
    clear -1
    show bitmap @4 # the stop signal
    readkey @3 $resttime # the remaining time up to 500 ms
    clear -1
  fi
  ### now stimulus/response stuff done, check whether mistake was made
  if $status1 == CORRECT
    clear -1
  fi
  if $status1 != TIMEOUT && $status1 != CORRECT
    show bitmap wrongkey
    delay 2000
    clear -1
    set $trialcorrect 0    
  fi
  if $status1 == TIMEOUT && STATUS != TIMEOUT
    show bitmap shouldnothavepressed1
    delay 250
    clear -1
    show bitmap shouldnothavepressed2
    delay 250
    clear -1
    show bitmap shouldnothavepressed1
    delay 250
    clear -1
    show bitmap shouldnothavepressed2
    delay 250
    clear -1
    show bitmap shouldnothavepressed1
    delay 250
    clear -1
    set $trialcorrect 0
  fi
  delay &iti
  save @1 $nogodelay $rt1 $status1 RT STATUS $trialcorrect

block baseline
  message instruction1
  tasklist
    go 20 allcorrect 50
  end
  feedback
    text 0 0 "Average response time in milliseconds"
    set &MyRT mean c4 ; postfix "ms" ; select c5 == 1
    text 0 50 &MyRT ; postfix "ms"
  end
   
block stopgo
  message instruction2
  tasklist
    go 30
    nogo 10
  end

Download

The PsyToolkit code zip file

If you have a PsyToolkit account, you can upload the zipfile directly to your PsyToolkit account. Watch a video on how to do that. If you want to upload the zipfile into your PsyToolkit account, make sure the file is not automatically uncompressed (some browsers, especially Mac Safari, by default uncompress zip files). Read here how to easily deal with this.

Stop signal task

Introduction

About this implementation

Timing of trials

Run the demo

Data output file

Analysis and data interpretation

PsyToolkit code

Download

Further reading