Introduction
In self-paced reading tasks, participants need to press a key to read a sentences word for word. There are different ways this can be implemented (Jegersky, 2013).
In this self-paced reading task, participants see an additional word each time they press a key (in this experiment, we use the N key).
You can add sentences to the table.
| See also the one-word-at-the-time version. |
About this implementation
This implementation uses various techniques. The sentences are as whole sentences in the table. The task breaks them apart into words, which then are added one to one to a textvariable (i.e., variables starting with a %).
In this implementation, a textbox is being used. Textboxes are good for rendering longer texts in PsyToolkit experiments. They make sure the text is wrapped appropriately.
| This experiment also uses the fillup array funtion. This makes sure that in the end, you have a data file with one row for each trial, and each trial is of the same size. Unused reaction time spots are filled up with -1 numbers. This can be handy when reading in your raw data files into statistical software. Make sure you fill up with at least as many values as the sentence with the maximum number of words. |
Run the demo
Data output file
| In PsyToolkit, the data output file is simply a textfile. The save line of the PsyToolkit experiment script determines what is being saved in the data output file. Typically, for each experimental trial, you would have exactly one line in your text file, and each number/word on that line gives you the information you need for your data analysis, such as the condition, response speed, and whether an error was made. |
Meaning of the columns in the output datafile. You need this information for your data analysis.
| Colum | Meaning |
|---|---|
1 |
number of words |
2 |
the sentence used |
3 |
the total reaction time (ms) for all words together |
4-20 |
the reaction times for each word separately |
PsyToolkit code
Click to expand the PsyToolkit script code (part of zip file below)
table sent
"John brought cookies for his mother. His father does not like cookies."
"Mary cooked dinner for her son and daughter. They like spicy fried beans with sauce."
"Clara is looking after her pets. She has cats and dogs."
"Mickey likes to take walks in the forest. Especially when Minnie joins him."
"Donald and Daisy enjoy bike rides along the beautiful lake in their home town."
task paced
keys n
show text "Press the n key to start see the first word." 0 -50
show text "Then press the n key each time for the following words." 0 50
readkey 1 9999
clear -1 -2
#
textbox new 0 0 700 400 white black
textbox 1 lock
#
set %%words split @1
set $l %%words size ## how many words
set %newword %%words remove first
set %newsentence %newword
set $mycounter 1
set &&reactionTimes clear
while $mycounter <= $l
textbox 1 text %newsentence
readkey 1 9999
clear -1
set &&reactionTimes append RT
set %newword %%words remove first
set %newsentence %newsentence " " %newword
set $mycounter increase
while-end
textbox 1 clear ## removes textbox
show text "Well done...just wait until next sentence"
delay 500
show text ". " 0 30
delay 500
show text ".. " 0 30
delay 500
show text "..." 0 30
delay 500
clear screen
set %sentence @1
set &&reactionTimes fillup 20 -1
save $l %sentence &&reactionTimes
block test
tasklist
paced 5
endDownload
| If you have a PsyToolkit account, you can upload the zipfile directly to your PsyToolkit account. Watch a video on how to do that. If you want to upload the zipfile into your PsyToolkit account, make sure the file is not automatically uncompressed (some browsers, especially Mac Safari, by default uncompress zip files). Read here how to easily deal with this. |
Further reading
-
Jegersky, J. (2013). Research Methods in Second Language Psycholinguistics. In Research Methods in Second Language Psycholinguistics by Jegerski, J. & VanPatten, B. Routledge: New York. ISBN: 9780203123430. Link to book overview.