Dot probe task

Introduction

The dot-probe task is not only popular in cognitive psychology, but also in other areas, such as educational and clinical psychology. In short, this tasks measures how much faster people respond to threatening stimuli compared to neutral stimuli.

A threatening stimulus can be a stimulus such as a word that makes your nervous or anxious. For example, if you have test anxiety, the word "exam" might make you slightly nervous. In some dot probe experiments words are used whereas in others images are used. In the current example we use words.

The first article published about it was by MacLeod and colleagues (1986). Since then, different versions have been developed.

About this implementation

In this study, we use the test anxiety dot-probe task by David Putwain and colleagues (2011). There are threatening words related to exams/tests, such as "exam" and "failure" and neutral words.

This test was originall designed for use in England. But because PsyToolkit is used around the world, in this implementation. If you want to adjust it for use outside the UK, you need to look for the words "GCSE". Also note that British spelling is used ("kilometre"). You can easily change these words yourself in the file mytable.txt.

The instructions are provided in the instructions.svg file (which you can open with an SVG editor such as Inkscape). Note that the rounded font used in the instructions might need to be downloaded additionally (if you do not have it, Inkscape will use a default font).

TIP In the original study, a survey measured test anxiety. If you like to do a similar study, PsyToolkit recommends a short test anxiety questionnaire. You can find the 5-question Test Anxiety Inventory in the PsyToolkit survey library.

Run the demo

In this example, you will

Click here to run a demo

Data output file

In PsyToolkit, the data output file is simply a textfile. The save line of the PsyToolkit experiment script determines what is being saved in the data output file. Typically, for each experimental trial, you would have exactly one line in your text file, and each number/word on that line gives you the information you need for your data analysis, such as the condition, response speed, and whether an error was made.

Meaning of the columns in the output datafile. You need this information for your data analysis.

Colum	Meaning
1	Condition. 1=Neutral, 2=threatening
2	Reaction time
3	Status (1=correct,2=wrong,3=too slow)
4	The probe position (1=top, 2=bottom)
5	The arrow direction (1=left, 2=right)
6	Row of table
7	Top word/phrase
8	Bottom word/phrase

PsyToolkit code

Click to expand the PsyToolkit script code (part of zip file below)

bitmaps
  i1
  i2
  i3

table mytable
  include mytable.txt
  
task dotprobe
  keys a l
  set $current &&my_trials remove random
  tablerow $current
  ## stimulus presentation starts
  show text "+++"
  delay 500
  clear -1
  show text @2 0 -30
  show text @3 0  30
  delay 500
  clear -1 -2
  if @2 == @3
    show text @5 0 -30
    set $probeposition 1
  else
    show text @5 0  30
    set $probeposition 2
  fi
  readkey @6 5000
  clear -1
  if STATUS == WRONG
    show text "Wrong key. Use A or L"
    delay 500
    clear -1
    delay 500
  fi
  if STATUS == TIMEOUT
    show text "Please respond more quickly"
    delay 500
    clear -1
    delay 500
  fi
  delay 500
  set %topword @2
  set %bottomword @3
  save BLOCKNUMBER @1 RT STATUS $probeposition @6 TABLEROW %topword %bottomword 

block training
  message i1
  message i2
  message i3
  set &&my_trials range 1 3
  tasklist
    dotprobe 3
  end

block part1
  message "Get ready for part 1, Press space bar to start."
  set &&my_trials range 4 99
  tasklist
    dotprobe 48
  end

block part2
  message "Get ready for part 2. Press space bar to start."
  tasklist
    dotprobe 48
  end
  feedback
    set &neutral mean c3 ; select c2 == 1
    set &anxiety mean c3 ; select c2 == 2
    text 0 -100 &neutral ; prefix "RT in neutral trials " ; postfix " ms"
    text 0  -50 &anxiety ; prefix "RT in anxiety trials " ; postfix " ms"
    text 0   50 "Press space to continue"
  end

Download

The PsyToolkit code zip file

If you have a PsyToolkit account, you can upload the zipfile directly to your PsyToolkit account. Watch a video on how to do that. If you want to upload the zipfile into your PsyToolkit account, make sure the file is not automatically uncompressed (some browsers, especially Mac Safari, by default uncompress zip files). Read here how to easily deal with this.

Dot probe task

Introduction

About this implementation

Run the demo

Data output file

PsyToolkit code

Download

Further reading